Buenas tardes a todos. Estoy intentado hacer o mas bien copiar un menu autoejecutable de disket, para hacer mi propio menu con los juegos que me interesan, el problema, que los diskets que tienen este tipo de menu no me deja listar el programa para modificarlo. Alguien tiene un programa tipo menu, o sabe como poder editar un autoexec.bas o autoexec.000 para poder ver programa menu, y modificarlo para hacer el mio. Muchas gracias a todos
EJEMPLO MENU AUTOEJECUTABLE (muy sencillo)
‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐-----------------
FICHERO AUTOEXEC.BAS
‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐
10 CLEAR 1000
20 ELEM$="123456789abcdefghijklmnopqrstuvwyxz"
30 POKE ‐1,170
40 CLS
50 PRINT
60 PRINT "Cargando la lista ";
70 OPEN "listado" FOR INPUT AS#1
80 DIM L$(35,2):NUM=1
90 INPUT#1,NOM$
100 IF NOM$="FIN" THEN GOTO 160
110 L$(NUM,1)=NOM$
120 INPUT#1,L$(NUM,2)
130 PRINT ".";
140 NUM=NUM+1
150 GOTO 90
160 CLOSE #1
170 CLS
180 KEY OFF
190 COLOR 11,1,1
200 PRINT "JUEGOS DISPONIBLES"
210 PRINT "‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐"
220 FOR I=1 TO NUM‐1
230 LOCATE (I\18)*20,(I MOD 18)+3
240 PRINT MID$(ELEM$,I,1);" ";L$(I,1)
250 NEXT I
260 LOCATE 0,22
270 PRINT "OPCION: (0 salir) ";
275 A$=INPUT$(1)
280 IF A$="0" GOTO 340
290 IF INSTR(ELEM$,A$)=0 THEN 170
300 COLOR 15: LOCATE 0,22
310 PRINT "Cargando ";L$(INSTR(ELEM$,A$),2);" . . . . "
320 RUN L$(INSTR(ELEM$,A$),2)
330 GOTO 170
340 CLS
350 PRINT "FIN del programa"
360 PRINT
370 FILES
380 END
FICHERO LISTADO
‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐
Juego formato bas
Juego1.bas
Juego formato bas
Juego2.bas
Juego formato bas
Juego3.bas
Juego formato bas
Juego4.bas
…
FIN
RESULTADO DE UN FILES
‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐
LISTADO
AUTOEXEC.BAS
Juego1.bas
…
Juego2.bas
…
Juego3.bas
…
Juego4.bas
Juego4.bin
…
La ejecución de cada fichero .bas
irá llamando a los distintos binarios,
por ejemplo:
JUEGO4.BAS
‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐‐
10 POKE ‐1,170
20 BLOAD "juego4.bin",R
Muchas gracias por vuestras respuesta, y muy interesante el programa y la estructura de los archivos. Como todavia no domino el basic, al programa faltaria el listado de los juegos y la ejecucion del los juegos como se decribe al final del comentario es decir si no voy mal encaminado..... A partir de la linea 210 por ejemplo 215 habria un print con la etiqueta de un juego, y la ejecucion bload"juego4.bin",r en que linea lo tendria que ejecutar? Si quiero una seleccion del 1 al 5, en el caso de 5 juegos, le falta incluir alguna cosa al programa? Muchas gracias por adelantado
El programa autoexec.bas funciona tal cual está...
El listado de juegos se escribe de la línea 210 a la 250...
Que va leyendo del fichero LISTADO que hay que crear.
Para selecciones de 1 a 5 sería pues necesario:
- El fichero LISTADO con 10 líneas + la línea FIN
- Los 5 ficheros .bas con sus correspondientes bload
Muy bien perfecto, ahora entendi, lo del archivo listado.... Es alli donde se edita las lineas para mostrar en pantalla las etiquetas de los distintos juegos, y el propio programa al seleccionar una etiqueta va a buscar su correspondiente .bas. Muy interesante, y siempre se aprende algo nuevo. Muchas gracias Panzer por tu explicacion y tu tiempo!
Buenas tardes Panzer. Este fin de semana me he dedicado a probar el programa que me pasaste y bien me he encallado en el archivo LISTADO. Entiendo como ejemplo que las lineas en el archivo LISTADO quedarian asi?
Ejemplo:
10 zanac
20 bload"zanac.bas"
30 fin
Me da error en la linea 120 de tu programa y me da la sensacion, que el problema es el fichero LISTADO que esta mal.
INPUT PAST END IN 120.
Buenas panzer. Entonces lo que no se es crear este tipo de archivo "LISTADO". Con mis conocimientos, desde el basic para crear un archivo mediante el save, tiene que ser un programa con su correspondiente numero de linea.10...20...30, porque si no da error al pensar que ejecuta una instruccion directamente. Tal como me lo comentar, que solo haya estas lineas sin numero de linea, es como si fuera un archivo de DOS, editado puramente con un editor, y poniendo cualquier tipo de texto dentro. Si es asi, se crea este archivo desde el MSX-DOS? o igualmete desde el Basic. Disculpa que pregunte tanto, pero pero es que me falta aprender mucho. Gracias.
Solucionado. Antes de escribir hay que provar. Al final edite desde el MSX-DOS un archivo listado, desde el programa TED, pensado que ese archivo desde el BASIC no iba a funcionar ni de coña y sorpresa, funcionando a la perfeccion. Otra vez gracias Panzer por tu paciencia!
