Turbo R - interrupt line issues

Is this avoidable by forcing off vdp interrupts during this period?

Can you explain a bit more? Does this mean an additional push/pop sequence before and after "call $fd9f" is expected? If so, that isn't a concern here because there isn't any further code happening here, and the pre-interrupt registers are restored right after.

ah thx

Thanks for the tips! I'll do some research and see if I can't get it working.

Thanks for the replies so far. I haven't figured it out, but I haven't given up yet either. Im properly saving all registers now as I should.

This I think is the path I should take, but I'm having trouble figuring out where/ at what time the status register needs to be saved. I took a look at the RST38h handler on F1XD, and it looks like this:

DDB4  ld     hl,(#ddd1)   2A D1 DD ; scratch location of current RAM stack pointer 
DDB7  ld     a,l          7D
DDB8  or     h            B4 ; A = SP low OR sp hi...?
DDB9  pop    hl           E1 ; 
DDBA  ld     ix,#0038     DD 21 38 00 ; RST38 location
DDBE  ld     iy,(#fcc0)   FD 2A C0 FC  ; FCC1-1 (mnrom)
DDC2  jr     nz,#dde7     20 23
DDC4  pop    af           F1
DDC5  ld     (#ddd1),sp   ED 73 D1 DD ; save sp 
DDC9  ld     sp,#dda8     31 A8 DD ; temporary sp 
DDCC  call   #001c        CD 1C 00  ; inter-slot call 
DDCF  di                  F3

Interestingly, it jumps to a location where it then performs another inter-slot RST38 (the mnrom handler). Well, know I know. Lots more work to be done...

I tried to find an example where RG15 was saved and restored for use in this situation - I know I saw it once before but now I am at a loss. Let me know if you have one off hand.

Hai,

I'm doing the same thing; custom ISR on #38 on turbo R. Works fine, nothing special needed for that machine.
The FD9F call, like GDX mentioned, is better to ignore unless you want diskdrives to stop spinning. But there's other methods for that.

on Vblank you call musica, make sure you save the right registers used by that replayer (unless its saving the regs on its own)

The only thing I could think of, is some slot switching going on (musica?) - if you have DOS enabled and page 0 is RAM this would just work.

Thanks all, I was closer than I thought - late-night error I fixed this morning. FS-A1ST confirmed working.

Some interesting notes, because I'm still not sure this method will work on *all* machines:
1. Install my own ISR at $0038 (<- what are some machines that might have strange behavior in their ISR...?)
2. My ISR does: Push/pop all, call $fd9a (possibly to reset a line?), ack vdp, call $fd9f (musica hooks itself, then runs previous fd9f code)

This removes the built-in interslot RST38, but as far as I can tell minus sprite collision, timer increment, and SOUND call my routine is now identical to MNROMs. Since this might be helpful for someone in the future to see in entirety:

org 0x100
    di 
    ; install ISR first thing 
    ld a,$c3 
    ld ($0038),a 
    ld hl,_irq 
    ld ($0039),hl 

    :load files using call 5, 
    :vdp writes, install music driver, etc

    ei 
    loop: jr loop 

_irq:
    ;di               ; exchange everything just in case
    push    hl
    push    de
    push    bc
    push    af
    exx
    ex      af,af'
    push    hl
    push    de
    push    bc
    push    af
    push    iy
    push    ix

    call $fd9a      ; possibly needed to reset an irq line on some machines? 
    
    ; vdp ack
    ld c,$99 
    ld a,0              ; status reg 0
    out (c),a 
    ld a,15+$80
    out (c),a
    in a,(c)   
    rlca                ; bit7 = vbl
    call nz,vblank ; if it was from the vdp, call vblank code 

    pop     ix
    pop     iy
    pop     af
    pop     bc
    pop     de
    pop     hl
    ex      af,af'
    exx
    pop     af
    pop     bc
    pop     de
    pop     hl
    ei
    ret            
    
    vblank:
        call $fd9f         ; mnrom calls this here as well btw 
    
        ld a,(0xc001)
        inc a 
        ld (0xc001),a   ; increment as a test once per frame 
    
        ret